ndk/packages/ndk_flutter/android/build.gradle at 477db936dab5c703d7404bbd5af2e56803f10488 · relaystr/ndk · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
group = 'relaystr.ndk'
version = '1.0-SNAPSHOT'

buildscript {
    repositories {
        google()
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:8.12.3'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:2.2.20"
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
    }
}

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'

android {
    if (project.android.hasProperty("namespace")) {
        namespace = 'relaystr.ndk'
    }

    compileSdk = 36

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }

    kotlinOptions {
        jvmTarget = '17'
    }

    sourceSets {
        main.java.srcDirs += 'src/main/kotlin'
        test.java.srcDirs += 'src/test/kotlin'
    }

    defaultConfig {
        minSdk = 21
    }

    dependencies {
        testImplementation 'org.jetbrains.kotlin:kotlin-test'
        testImplementation 'org.mockito:mockito-core:5.23.0'
        implementation 'com.google.code.gson:gson:2.13.2'
        implementation 'fr.acinq.secp256k1:secp256k1-kmp-jni-android:0.23.0'
    }

    testOptions {
        unitTests.all {
            useJUnitPlatform()
            testLogging {
                events "passed", "skipped", "failed", "standardOut", "standardError"
                outputs.upToDateWhen { false }
                showStandardStreams = true
            }
        }
    }
}

subprojects {
    afterEvaluate { project ->
        if (project.extensions.findByName("android") != null) {
            // Raise any plugin still stuck on old compileSdk values to 36
            Integer pluginCompileSdk = project.android.compileSdk
            if (pluginCompileSdk != null && pluginCompileSdk < 33) {
                project.logger.warn(
                        "Warning: Overriding compileSdk in plugin '${project.name}' " +
                                "from ${pluginCompileSdk} to 36."
                )
                project.android {
                    compileSdk = 36
                }
            }


            project.android.compileOptions {
                sourceCompatibility = JavaVersion.VERSION_17
                targetCompatibility = JavaVersion.VERSION_17
            }
        }
        project.tasks.withType(JavaCompile).configureEach {
            sourceCompatibility = JavaVersion.VERSION_17
            targetCompatibility = JavaVersion.VERSION_17
        }
    }

    layout.buildDirectory = rootProject.layout.buildDirectory.dir(project.name)
    project.evaluationDependsOn(":app")
}