clue/build.gradle at master · javasoze/clue · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
plugins {
    id 'java'
    id 'application'
    id 'maven-publish'
}

group = 'io.dashbase.clue'
def baseVersion = '1.0.0-10.2.2'
def isSnapshot = (project.findProperty('snapshot') ?: System.getenv('CLUE_SNAPSHOT'))?.toString()?.toBoolean()
version = isSnapshot ? "${baseVersion}-SNAPSHOT" : baseVersion
description = 'command line client for Apache Lucene'

ext {
    luceneVersion = '10.2.2'
    retrofit2Version = '2.5.0'
    micronautVersion = '5.0.0-M5'
}

repositories {
    mavenCentral()
    maven { url 'https://oss.sonatype.org/content/repositories/releases' }
    maven { url 'https://repository.apache.org/snapshots/' }
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

application {
    mainClass = 'io.dashbase.clue.ClueApplication'
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }
    repositories {
        maven {
            name = 'GitHubPackages'
            url = uri('https://maven.pkg.github.com/javasoze/clue')
            credentials {
                username = System.getenv('GITHUB_ACTOR')
                password = System.getenv('GITHUB_TOKEN')
            }
        }
    }
}

dependencies {
    implementation "org.apache.lucene:lucene-core:${luceneVersion}"
    implementation "org.apache.lucene:lucene-codecs:${luceneVersion}"
    implementation "org.apache.lucene:lucene-analysis-common:${luceneVersion}"
    implementation "org.apache.lucene:lucene-backward-codecs:${luceneVersion}"
    implementation "org.apache.lucene:lucene-queries:${luceneVersion}"
    implementation "org.apache.lucene:lucene-queryparser:${luceneVersion}"
    implementation "org.apache.lucene:lucene-facet:${luceneVersion}"

    // https://mvnrepository.com/artifact/tools.jackson.core/jackson-databind
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.20.1'
// https://mvnrepository.com/artifact/tools.jackson.dataformat/jackson-dataformat-yaml
    implementation 'com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.20.1'
    annotationProcessor "io.micronaut:micronaut-inject-java:${micronautVersion}"
    implementation "io.micronaut:micronaut-runtime:${micronautVersion}"
    implementation "io.micronaut:micronaut-http:${micronautVersion}"
    implementation "io.micronaut:micronaut-http-server:${micronautVersion}"
    implementation "io.micronaut:micronaut-http-server-netty:${micronautVersion}"
    implementation "io.micronaut:micronaut-jackson-databind:${micronautVersion}"
    implementation "jakarta.annotation:jakarta.annotation-api:2.1.1"
    runtimeOnly "ch.qos.logback:logback-classic:1.4.14"
    runtimeOnly "ch.qos.logback:logback-core:1.4.14"

    implementation "com.squareup.retrofit2:retrofit:${retrofit2Version}"
    implementation "com.squareup.retrofit2:converter-scalars:${retrofit2Version}"
    implementation "com.squareup.retrofit2:converter-jackson:${retrofit2Version}"

    implementation 'jline:jline:2.12'
    implementation 'info.picocli:picocli:4.7.5'
    implementation 'javax.xml.bind:jaxb-api:2.3.0'
    implementation 'com.sun.xml.bind:jaxb-core:2.3.0'
    implementation 'com.sun.xml.bind:jaxb-impl:2.3.0'
    implementation 'javax.activation:activation:1.1.1'

    testImplementation 'org.junit.jupiter:junit-jupiter:5.11.0'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

tasks.register('copyRuntimeLibs', Copy) {
    from configurations.runtimeClasspath
    into layout.buildDirectory.dir('libs')
}

tasks.named('startScripts') {
    dependsOn tasks.named('copyRuntimeLibs')
}

tasks.named('assemble') {
    dependsOn tasks.named('copyRuntimeLibs')
}

tasks.named('test') {
    useJUnitPlatform()
}