build.gradle

plugins {
    alias(libs.plugins.android.application)
    alias(libs.plugins.kotlin.compose)
    alias(libs.plugins.ksp)
    alias(libs.plugins.google.services)
    alias(libs.plugins.firebase.crashlytics)
}

def keystorePropertiesFile = rootProject.file("keystore.properties")
def keystoreProperties = new Properties()
if (keystorePropertiesFile.exists() && keystorePropertiesFile.canRead()) {
    keystoreProperties.load(new FileInputStream(keystorePropertiesFile))
}

android {
    namespace 'io.github.gmathi.novellibrary'
    compileSdk 36
    buildToolsVersion '36.0.0'
    
    defaultConfig {
        applicationId "io.github.gmathi.novellibrary"
        minSdk 23
        targetSdk 36
        multiDexEnabled true
        versionCode 122
        versionName "1.1.0"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        vectorDrawables.useSupportLibrary = true
    }

    signingConfigs {
        if (keystorePropertiesFile.exists() && keystorePropertiesFile.canRead()) {
            release {
                keyAlias keystoreProperties['keyAlias']
                keyPassword keystoreProperties['keyPassword']
                storeFile file(keystoreProperties['storeFile'])
                storePassword keystoreProperties['storePassword']
            }
        }
    }

    buildTypes {
        debug {
            pseudoLocalesEnabled true
            getIsDefault().set(true)
        }

        release {
            if (keystorePropertiesFile.exists() && keystorePropertiesFile.canRead()) {
                signingConfig signingConfigs.release
            }
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    flavorDimensions = ["mode"]
    productFlavors {
        mirror {
            dimension "mode"
            applicationIdSuffix ".mirror"
        }

        canary {
            dimension "mode"
        }

        normal {
            dimension "mode"
            getIsDefault().set(true)
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }

    kotlin {
        compilerOptions {
            jvmTarget.set(org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_17)
        }
    }

    buildFeatures {
        dataBinding true
        viewBinding true
        buildConfig true
        compose true
    }
    
    sourceSets {
        mirror {
            res {
                srcDirs 'src\\mirror\\res'
            }
        }
    }

    packaging {
        jniLibs {
            useLegacyPackaging = false
        }
        resources {
            excludes += ['META-INF/DEPENDENCIES', 'META-INF/LICENSE', 'META-INF/LICENSE.txt', 'META-INF/NOTICE', 'META-INF/NOTICE.txt']
        }
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar', '*.aar'])
    
    // Foundation modules
    implementation project(':core')
    implementation project(':common')
    implementation project(':util')
    implementation project(':stubs')
    
    // Settings module
    implementation project(':settings')
    
    // AndroidX
    implementation libs.androidx.appcompat
    implementation libs.androidx.constraintlayout
    implementation libs.androidx.browser
    implementation libs.bundles.androidx.lifecycle
    implementation libs.androidx.legacy.support
    implementation libs.androidx.cardview
    implementation libs.androidx.vectordrawable
    implementation libs.androidx.preference
    
    // Compose
    implementation platform(libs.compose.bom)
    implementation libs.bundles.compose
    debugImplementation libs.compose.ui.tooling
    
    // Material Design
    implementation libs.material
    
    // WorkManager
    implementation libs.bundles.work
    androidTestImplementation libs.androidx.work.testing
    
    // Network
    implementation libs.bundles.network
    
    // Reactive
    implementation libs.bundles.reactive
    
    // Kotlin
    implementation libs.bundles.kotlinx
    
    // Parsing & Data
    implementation libs.jsoup
    implementation libs.gson
    implementation libs.kotson
    implementation libs.markdown
    
    // Image Loading
    implementation libs.bundles.image.loading
    implementation libs.coil.compose
    implementation libs.landscapist.core
    ksp libs.glide.ksp
    
    // UI Components
    implementation libs.lottie
    implementation libs.photoview
    implementation libs.fancybuttons
    implementation libs.smarttablayout
    implementation libs.recyclerview.animators
    implementation libs.konfetti
    implementation libs.snackprogressbar
    
    // Material Dialogs
    implementation libs.bundles.material.dialogs
    
    // Firebase
    implementation platform(libs.firebase.bom)
    implementation libs.firebase.analytics
    implementation libs.firebase.core
    implementation libs.firebase.config
    implementation libs.firebase.crashlytics
    implementation libs.firebase.messaging
    implementation libs.firebase.auth
    implementation(libs.firebase.ui.auth) {
        exclude group: 'com.google.firebase'
        exclude group: 'com.google.android.gms'
        exclude group: 'com.android.support'
        exclude group: 'com.google.api-client'
        exclude group: 'com.google.apis'
    }
    
    // Google Play Services
    implementation libs.play.services.gcm
    implementation libs.play.services.drive
    implementation libs.play.services.auth
    implementation libs.google.api.client.android
    implementation(libs.google.api.services.drive) {
        exclude group: 'org.apache.httpcomponents'
        exclude group: 'com.google.guava'
    }
    
    // Utilities
    implementation libs.eventbus
    implementation libs.crux
    implementation libs.injekt
    
    // Debug
    canaryImplementation libs.leakcanary
    
    // Testing
    testImplementation libs.junit
    androidTestImplementation libs.androidx.junit
    androidTestImplementation libs.androidx.espresso
}

tasks.register('countTranslations') {
    File json = file('src\\main\\assets\\translations.json')

    Set<File> resources = fileTree('src\\main\\res')
            .files.findAll { (it.name == 'strings.xml') }
    File englishResources = resources.find { it.parentFile.name == 'values' }
    resources.remove(englishResources)

    List<String> englishStrings = englishResources.text.readLines()
            .findAll { it.trim().startsWith('<string name="') && !it.contains('translatable="false"') && it.endsWith('</string>') }
            .collect { it.trim().split('">')[1].split('</')[0] }

    json.text = '{\r\n  "en": "' + englishStrings.size() + '"'

    resources.each { resource ->
        List<String> strings = resource.text.readLines()
                .findAll { it.trim().startsWith('<string name="') && !it.contains('translatable="false"') && it.endsWith('</string>') }
                .collect { it.trim().split('">')[1].split('</')[0] }
                .findAll { !englishStrings.contains(it) }
        json.text += ',\r\n  "' + resource.parentFile.name.split('-')[1] + '": "' + strings.size() + '"'
    }

    json.text += '\r\n}'
}