fulibWorkflows/build.gradle at main · fujaba/fulibWorkflows · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
// --------------- Plugins ---------------

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'signing'
    id 'idea'
    // https://plugins.gradle.org/plugin/org.fulib.fulibGradle
    id 'org.fulib.fulibGradle' version '0.5.0'
    // https://plugins.gradle.org/plugin/io.github.gradle-nexus.publish-plugin
    id 'io.github.gradle-nexus.publish-plugin' version '1.1.0'

    // for service
    id 'org.springframework.boot' version '2.5.6' apply false
    id 'io.spring.dependency-management' version '1.0.11.RELEASE' apply false
}

// --------------- General Settings ---------------

def tag = 'git describe --tags'.execute([], rootDir).text[1..-2] // strip v and \n
allprojects {
    group = 'org.fulib'
    version = tag
    sourceCompatibility = 17
    targetCompatibility = 17
}

description = 'fulibWorkflows is a tool to generate mockups and object-/class-diagrams from a workflow description.'

// --------------- Dependencies ---------------

repositories {
    mavenLocal()
    mavenCentral()
}

nexusPublishing.repositories.sonatype()

java {
    withJavadocJar()
    withSourcesJar()
}

publishing.publications.create('mavenJava', MavenPublication) {
    it.from(components.java)
    it.pom {
        name = project.name
        description = project.description
        url = 'https://github.com/fujaba/fulibWorkflows'
        inceptionYear = '2019'

        scm {
            url = 'https://github.com/fujaba/fulibWorkflows'
        }

        licenses {
            license {
                name = 'MIT License'
                url = 'https://www.opensource.org/licenses/mit-license.php'
            }
        }

        developers {
            developer {
                id = 'zuendorf'
                name = 'Albert Zuendorf'
            }
            developer {
                id = 'Clashsoft'
                name = 'Adrian Kunz'
            }
            developer {
                id = 'Kuenssi'
                name = 'Maximilian Freiherr von Kuenssberg'
            }
        }
    }
}

signing.sign publishing.publications.mavenJava

dependencies {
    implementation group: 'org.json', name: 'json', version: '20090211'

    // https://mvnrepository.com/artifact/com.fasterxml.jackson.dataformat/jackson-dataformat-yaml
    implementation group: 'com.fasterxml.jackson.dataformat', name: 'jackson-dataformat-yaml', version: '2.13.1'

    // https://mvnrepository.com/artifact/org.antlr/ST4
    implementation group: 'org.antlr', name: 'ST4', version: '4.3.1'

    // https://mvnrepository.com/artifact/org.antlr/antlr4-runtime
    implementation group: 'org.antlr', name: 'antlr4-runtime', version: '4.9.3'

    // https://mvnrepository.com/artifact/org.fulib/fulibScenarios
    fulibScenarios group: 'org.fulib', name: 'fulibScenarios', version: '1.7.0'

    // https://mvnrepository.com/artifact/org.fulib/fulibTools
    implementation group: 'org.fulib', name: 'fulibTools', version: '1.5.1'

    // https://mvnrepository.com/artifact/guru.nidi/graphviz-java
    implementation group: 'guru.nidi', name: 'graphviz-java-all-j2v8', version: '0.18.1'

    // https://mvnrepository.com/artifact/org.fulib/fulibTables
    testImplementation group: 'org.fulib', name: 'fulibTables', version: '1.4.0'

    // https://mvnrepository.com/artifact/org.fulib/fulibMockups
    testImplementation group: 'org.fulib', name: 'fulibMockups', version: '0.4.0'

    // https://mvnrepository.com/artifact/junit/junit
    testImplementation group: 'junit', name: 'junit', version: '4.13'

    // https://mvnrepository.com/artifact/org.slf4j/slf4j-nop
    testImplementation group: 'org.slf4j', name: 'slf4j-nop', version: '1.7.30'
}

generateScenarioSource {
    classDiagramSVG = true
}