fugue-sleighc/flake.nix at ghidra-v12.1.2 · fugue-re/fugue-sleighc · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
{
  description = "Wrapper around Ghidra's SLEIGH specification compiler";

  inputs.nixpkgs.url = "github:nixos/nixpkgs/nixos-25.05";

  outputs =
    { self, nixpkgs }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;

      cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);

      buildDeps =
        pkgs: with pkgs; [
          bison
          cmake
          flex
          zlib
        ];

      mkSleighc =
        pkgs:
        pkgs.stdenv.mkDerivation {
          pname = "sleighc";
          version = cargoToml.package.version;
          src = ./vendored;
          cmakeFlags = [
            "-DCMAKE_INSTALL_LIBDIR=lib"
            "-DBUILD_COMPILER=ON"
            "-DBUILD_DECOMPILER=OFF"
          ];
          buildInputs = buildDeps pkgs;
        };
    in
    {
      packages = forAllSystems (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
          sleighc = mkSleighc pkgs;
        in
        {
          inherit sleighc;
          default = sleighc;
        }
      );

      devShells = forAllSystems (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
        in
        {
          default = pkgs.mkShell {
            name = "sleighc-dev";
            buildInputs =
              (buildDeps pkgs)
              ++ [
                pkgs.git
                self.packages.${system}.sleighc
              ];
          };
        }
      );
    };
}