ToxSuite/ToxSuite.pro at master · bignaux/ToxSuite · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
QMAKE_CFLAGS = -std=gnu99 -Wall -Wno-unused-parameter -Wno-unused-result -Wformat-security
# -Wno-unused

#TEMPLATE = app
CONFIG += console
CONFIG -= app_bundle
CONFIG -= qt
CONFIG -= captcha

# link with gcc instead of g++
QMAKE_LINK = $$QMAKE_LINK_C
#QMAKE_LFLAGS += -Wl,--as-needed

unix: CONFIG += link_pkgconfig ## enable the PKGCONFIG feature
unix: PKGCONFIG += libsodium
unix: PKGCONFIG += libtoxcore

VERSION    = 0.0.1
GIT_VERSION = $$system(git describe --abbrev=8 --dirty --always --tags)
DEFINES += GIT_VERSION=\\\"$$GIT_VERSION\\\"
DEFINES += VERSION=\\\"$$VERSION\\\"

# retroshare remove this :
#DEFINES += BE_DEBUG_DECODE
DEFINES += BE_DEBUG

# dirty lib, disabled.
captcha {
    captcha.target = .buildfile
    captcha.commands = make -f src/captcha/Makefile
    QMAKE_EXTRA_TARGETS += captcha
    PRE_TARGETDEPS += .buildfile
    LIBS += src/captcha/libcaptcha.o
    DEFINES += CAPTCHA
}


# on container :
# $ ldd --version
# ldd (Ubuntu EGLIBC 2.15-0ubuntu10.13) 2.15
# clock_gettime() : Link with -lrt (only for glibc versions before 2.17).
TRAVIS = $$(TRAVIS)
!isEmpty(TRAVIS) {
    LIBS += -lrt
    # workaround to use static toxcore lib build against a recent glibc
    # The pb occurs in this case :
    #  * you're using old glibc < 2.17 2
    #  * you don't use toxcore/network.c at all.
    #  * you're not using clock_gettime() in your software
    QMAKE_LFLAGS += -Wl,--no-as-needed
}

suit {
    TARGET = suit
    HEADERS += \
        src/call.h \
        src/command.h \
        src/suit.h \
        src/jsmn/jsmn.h \
        src/file.h \
        src/friend.h \
        src/list.h \
        src/toxdata.h \
        src/ylog/ylog.h \
        src/unused.h \
        src/timespec.h \
        src/misc.h \
        src/callbacks.h\
        src/conf.h\
        src/fileop.h\
        src/filesend.h\
        src/bencode/bencode.h \
        src/tsfiles.h

    SOURCES += \
        src/call.c \
        src/command.c \
        src/suit.c \
        src/jsmn/jsmn.c \
        src/file.c \
        src/friend.c \
        src/toxdata.c \
        src/ylog/ylog.c \
        src/timespec.c \
        src/misc.c \
        src/conf.c \
        src/fileop.c \
        src/filesend.c \
        src/callbacks.c\
        src/bencode/bencode.c \
        src/tsfiles.c

    unix: PKGCONFIG += sndfile
    unix: PKGCONFIG += libtoxav
}

toxdatatool {
  TARGET = toxdatatool
  LIBS += -lpopt
  unix:TEMPLATE = app
  CONFIG -= staticlib
  CONFIG += static
  HEADERS += \
    src/friend.h \
    src/list.h \
    src/toxdata.h \
    src/ylog/ylog.h \
    src/misc.h
  SOURCES += \
    src/toxdatatool.c \
    src/friend.c \
    src/toxdata.c \
    src/ylog/ylog.c \
    src/misc.c
}

#toxdatatool.path = /usr/bin
#suit.path = /usr/bin/
#INSTALLS += suit toxdatatool
#QMAKE_EXTRA_TARGETS += suit toxdatatool