build.gradle

plugins {
  id 'com.axelor.app'
  id 'com.github.node-gradle.node' version '7.1.0'
}

ext {
  myHomeAppDir = 'my-home'
}

axelor {
  title = 'Axelor :: DEMO'
}

allprojects {
  apply plugin: 'idea'
  apply plugin: 'eclipse'

  group = 'com.axelor'
  version = '8.2.0'

  java {
    toolchain {
      languageVersion = JavaLanguageVersion.of(21)
    }
  }

  afterEvaluate {
    test {
      useJUnitPlatform()
      beforeTest { descriptor ->
        logger.lifecycle('Running: ' + descriptor)
      }
    }
  }
}

dependencies {
  // add module dependencies
  implementation project(':modules:demo-contact')
  implementation project(':modules:demo-sale')
  implementation project(':modules:demo-project')
  implementation project(':modules:demo-custom')
}

war {
  archiveFileName = 'open-platform-demo.war'
}

i18n {
  extraSources = ["${myHomeAppDir}/src"]
}

apply from: 'gradle/style.gradle'

////
// My home app
////

node {
  version = '24.13.1'
  pnpmVersion = '10.33.4'
  download = true
  nodeProjectDir = file("${myHomeAppDir}")
  // Set distBaseUrl to null to prevent the Node plugin from injecting its own repository.
  // Else is bypass the centralized repository declarations (settings.gradle)
  distBaseUrl = null
}

tasks.register('buildMyHomeApp', PnpmTask) {
  def frontDist = file("${myHomeAppDir}/dist")
  outputs.dir(frontDist)

  // the up-to-date doesn't work as the plugin is used two times : here in root project
  // and when using aop includeBuild to built the main front.

  // Instead, build my-home application if the dist doesn't exist or if the task is invoked explicitly
  onlyIf {
    boolean outputExists = frontDist.exists() && frontDist.list()?.length > 0
    boolean isExplicitlyRequested = gradle.startParameter.taskNames.any { requestedTask ->
      requestedTask == name || requestedTask == path
    }
    return isExplicitlyRequested || !outputExists
  }

  dependsOn 'pnpmInstall'
  args = ['run', 'build']
}

clean {
  delete "${myHomeAppDir}/dist"
  delete "${myHomeAppDir}/node_modules"
}

tasks.register("copyMyHomeApp", Copy) {
  dependsOn 'buildMyHomeApp'
  from tasks.named('buildMyHomeApp').get().outputs
  into layout.buildDirectory.dir("webapp/${myHomeAppDir}")
}

tasks.named("copyWebapp") {
  dependsOn 'copyMyHomeApp'
}