stm32h7: Allow static placement in SRAM2 and SRAM4

Add SRAM2 and SRAM4 MEMORY regions with .sram2/.sram4 output sections
so code can place buffers there via __attribute__((section(".sram2")))
or .sram4. The runtime heap setup now starts above any statically
allocated content via the _esram2/_esram4 linker symbols, mirroring how
the regular heap starts above _ebss.

The SRAM4 region length excludes the 512-byte crashlog buffer at the
top of SRAM4 so it can never be allocated over.

The shared region/section definitions live in stm32h7_sram.ld and are
included by both stm32h7.ld and stm32h7_bootloader.ld.

Author: andoma

src/platform/stm32h7/stm32h7.c

@@ -114,13 +114,15 @@ stm32h7_init(void)
     // SRAM2
     mpu_add_region((void *)0x30004000, 14,
                    MPU_NORMAL_NON_SHARED_NON_CACHED | MPU_AP_RW | MPU_XN);
-    heap_add_mem(0x30004000, 0x30008000,
+    extern uint8_t _esram2[];
+    heap_add_mem((long)_esram2, 0x30008000,
                  MEM_TYPE_DMA | MEM_TYPE_NO_CACHE, 30);
 
     // SRAM4
     mpu_add_region((void *)0x38000000, 14,
                    MPU_NORMAL_NON_SHARED_NON_CACHED | MPU_AP_RW | MPU_XN);
-    heap_add_mem(0x38000000, CRASHLOG_ADDR,
+    extern uint8_t _esram4[];
+    heap_add_mem((long)_esram4, CRASHLOG_ADDR,
                  MEM_TYPE_DMA | MEM_TYPE_NO_CACHE, 40);
     break;
   }

src/platform/stm32h7/stm32h7.ld

@@ -4,4 +4,5 @@ MEMORY {
          RAM   (xrw): ORIGIN = 0x20000400, LENGTH = 128K
 }
 
+INCLUDE platform/stm32h7/stm32h7_sram.ld
 INCLUDE cpu/cortexm/cortexm.ld

src/platform/stm32h7/stm32h7_bootloader.ld

@@ -17,4 +17,5 @@ SECTIONS {
         } >BOOT
 }
 
+INCLUDE platform/stm32h7/stm32h7_sram.ld
 INCLUDE cpu/cortexm/cortexm.ld

src/platform/stm32h7/stm32h7_sram.ld

@@ -0,0 +1,33 @@
+/* SRAM2 and SRAM4 regions shared by the application and bootloader
+ * linker scripts. Placement in these regions is opt-in via the .sram2
+ * and .sram4 input sections. _esram2 / _esram4 mark the end of any
+ * statically allocated content so the heap can be added above it.
+ *
+ * The last 512 bytes of SRAM4 are reserved for the crashlog buffer
+ * (see CRASHLOG_ADDR in stm32h7.c) and excluded from the region.
+ */
+
+MEMORY {
+         SRAM2 (xrw): ORIGIN = 0x30004000, LENGTH = 16K
+         SRAM4 (xrw): ORIGIN = 0x38000000, LENGTH = 16K - 512
+}
+
+SECTIONS {
+        .sram2 (NOLOAD) : {
+                . = ALIGN(4);
+                _ssram2 = .;
+                KEEP(*(.sram2))
+                KEEP(*(.sram2.*))
+                . = ALIGN(4);
+                _esram2 = .;
+        } >SRAM2
+
+        .sram4 (NOLOAD) : {
+                . = ALIGN(4);
+                _ssram4 = .;
+                KEEP(*(.sram4))
+                KEEP(*(.sram4.*))
+                . = ALIGN(4);
+                _esram4 = .;
+        } >SRAM4
+}