vine/flake.nix at main · VineLang/vine · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    crane.url = "github:ipetkov/crane";
    typix = {
      url = "github:loqusion/typix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    typsitter = {
      url = "github:TendrilsCompute/typsitter";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    hyptyp = {
      url = "github:TendrilsCompute/hyptyp";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      nixpkgs,
      flake-utils,
      rust-overlay,
      crane,
      typix,
      typsitter,
      hyptyp,
      treefmt-nix,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ rust-overlay.overlays.default ];
        };

        rustToolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
        craneLib = (crane.mkLib pkgs).overrideToolchain (_: rustToolchain);

        self.cli = import ./cli/cli.nix {
          inherit pkgs craneLib;
        };

        self.tests = import ./tests/tests.nix {
          inherit
            pkgs
            flake-utils
            rustToolchain
            craneLib
            ;
          inherit (self) cli;
        };

        self.grammars = import ./lsp/grammars.nix {
          inherit pkgs;
        };

        self.docs = import ./docs/docs.nix {
          inherit
            system
            pkgs
            flake-utils
            hyptyp
            typix
            typsitter
            ;
          inherit (self) grammars cli;
        };

        self.style = import ./style.nix {
          inherit pkgs treefmt-nix;
          inherit (self) cli;
        };
      in
      builtins.foldl' pkgs.lib.attrsets.recursiveUpdate {
        packages.default = self.cli.packages.vine;

        devShells.default = craneLib.devShell {
          name = "vine-dev";
          packages = [
            pkgs.cargo-expand
            pkgs.nushell
            pkgs.nodejs_24
            pkgs.tree-sitter
          ];
        };
      } (builtins.attrValues self)
    );
}