MidnightLib/settings.gradle.kts at multiversion · TeamMidnightDust/MidnightLib · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
pluginManagement {
    repositories {
        mavenCentral()
        gradlePluginPortal()
        maven("https://maven.fabricmc.net/")
        maven("https://maven.architectury.dev")
        maven("https://maven.minecraftforge.net")
        maven("https://maven.neoforged.net/releases/")
        maven("https://maven.kikugie.dev/snapshots")
    }
}

plugins {
    id("dev.kikugie.stonecutter") version "0.9"
}

stonecutter {
    kotlinController = true
    shared {
        fun mc(loader: String, vararg versions: String) {
            for (version in versions) {
                val buildscript = when {
                    sc.eval(version, ">= 26.1-pre-1") && loader == "fabric" -> "build-unobfuscated-fabric.gradle.kts"
                    sc.eval(version, ">= 26.1-pre-1") && loader == "neoforge" -> "build-unobfuscated-neoforge.gradle.kts"
                    else -> "build-obfuscated.gradle.kts"
                }
                version("$version-$loader", version).buildscript(buildscript)
            }
        }
        mc("fabric","1.20.1", "1.21.1", "1.21.5", "1.21.8", "1.21.10", "1.21.11", "26.1-pre-3", "26.1")
        //mc("fabric", "26.1-rc-1")
        //mc("forge","1.20.1")
        mc("neoforge", "1.21.1", "1.21.5", "1.21.8", "1.21.10", "1.21.11", "26.1")
    }
    create(rootProject)
}

rootProject.name = "MidnightLib"