klay/CMakeLists.txt at main · ML-KULeuven/klay · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
cmake_minimum_required(VERSION 3.15...3.27)
project(klaycircuits LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

if (NOT SKBUILD)
    message(WARNING "\
  This CMake file is meant to be executed using 'scikit-build'. Running
  it directly will almost certainly not produce the desired result. If
  you are a user trying to install this package, please use the command
  below, which will install all necessary build dependencies, compile
  the package in an isolated environment, and then install it.
  =====================================================================
   $ pip install .
  =====================================================================
  If you are a software developer, and this is your own package, then
  it is usually much more efficient to install the build dependencies
  in your environment once and use the following command that avoids
  a costly creation of a new virtual environment at every compilation:
  =====================================================================
   $ pip install nanobind scikit-build-core[pyproject]
   $ pip install --no-build-isolation -ve .
  =====================================================================
  You may optionally add -Ceditable.rebuild=true to auto-rebuild when
  the package is imported. Otherwise, you need to re-run the above
  after editing C++ files.")
endif()

# -----------------------------------------------
# DEPENDENCIES
# -----------------------------------------------

include(GNUInstallDirs)

find_package(Python 3.10
        REQUIRED COMPONENTS Interpreter Development.Module
        OPTIONAL_COMPONENTS Development.SABIModule)

find_package(nanobind CONFIG REQUIRED)

# -----------------------------------------------
# LIBRARY KLAY
# -----------------------------------------------

add_library(klay SHARED
  src/circuit.cpp
  src/node.cpp
)

set_target_properties(klay PROPERTIES
  WINDOWS_EXPORT_ALL_SYMBOLS ON
)

target_include_directories(klay
  PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:klay/include>
)

install(TARGETS klay
  EXPORT klayTargets
  LIBRARY DESTINATION klay
  RUNTIME DESTINATION klay
)

install(DIRECTORY include/
  DESTINATION klay/include
)

install(EXPORT  klayTargets
  FILE        klayConfig.cmake
  DESTINATION klay/cmake/klay
)

# -----------------------------------------------
# PYTHON KLAY EXTENSION
# -----------------------------------------------

nanobind_add_module(klay_ext
  STABLE_ABI
  NOMINSIZE
  NB_STATIC
  src/klay_bindings.cpp
  src/indices.cpp
)

target_link_libraries(klay_ext PRIVATE klay)

set(RPATH_ORIGIN "$ORIGIN")
if(APPLE)
  set(RPATH_ORIGIN "@loader_path")
endif()

set_target_properties(klay_ext PROPERTIES
  INSTALL_RPATH "${RPATH_ORIGIN}"
  BUILD_WITH_INSTALL_RPATH TRUE
)

install(TARGETS klay_ext LIBRARY DESTINATION klay)

# -----------------------------------------------
# PYTHON KLAY EXTENSION STUBS
# -----------------------------------------------
# nanobind_add_stub(
#   klay_ext_stub
#   INSTALL_TIME
#   MODULE klay_ext
#   OUTPUT klay/klay_ext.pyi
#   PYTHON_PATH "klay"
#   MARKER_FILE klay/py.typed
#   DEPENDS klay_ext
# )
# install(FILES "${CMAKE_BINARY_DIR}/klay_ext.pyi" DESTINATION klay)