CMakeLists.txt

cmake_minimum_required(VERSION 3.22)
project(
    waterlinkedsonar
    VERSION 0.1.0
    LANGUAGES CXX
    DESCRIPTION "C++ client library for the Water Linked Sonar 3D-15"
    HOMEPAGE_URL "https://github.com/BumblebeeAS/waterlinkedsonar"
)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)

option(
    WATERLINKEDSONAR_BUILD_EXAMPLES
    "Build the example programs"
    ${PROJECT_IS_TOP_LEVEL}
)
if(PROJECT_IS_TOP_LEVEL)
    include(CTest)
endif()

# Protobuf >= 4.22 links against Abseil, and only protobuf's own config
# package declares that dependency; CMake's FindProtobuf module hands out a
# bare protobuf::libprotobuf that fails to link against it. Prefer config
# mode and fall back to the module for the pre-4.x protobuf that Ubuntu ships.
find_package(Protobuf CONFIG QUIET)
if(NOT Protobuf_FOUND)
    find_package(Protobuf MODULE REQUIRED)
endif()
find_package(CURL REQUIRED)
find_package(Snappy REQUIRED)
find_package(ZLIB REQUIRED)
find_package(nlohmann_json REQUIRED)

set(proto_file
    ${CMAKE_CURRENT_SOURCE_DIR}/proto/WaterLinkedSonarIntegrationProtocol.proto
)
set(proto_out_dir ${CMAKE_CURRENT_BINARY_DIR}/generated)
set(proto_gen_cc ${proto_out_dir}/WaterLinkedSonarIntegrationProtocol.pb.cc)
set(proto_gen_h ${proto_out_dir}/WaterLinkedSonarIntegrationProtocol.pb.h)
add_custom_command(
    OUTPUT ${proto_gen_cc} ${proto_gen_h}
    COMMAND ${CMAKE_COMMAND} -E make_directory ${proto_out_dir}
    COMMAND
        protobuf::protoc --cpp_out=${proto_out_dir} -I
        ${CMAKE_CURRENT_SOURCE_DIR}/proto ${proto_file}
    DEPENDS ${proto_file}
    COMMENT "Generating protobuf sources"
)
# Tests that construct protobuf messages depend on this target so the
# generated header exists before their objects compile.
add_custom_target(
    waterlinkedsonar_proto_gen
    DEPENDS ${proto_gen_cc} ${proto_gen_h}
)

add_library(waterlinkedsonar SHARED)
add_library(waterlinkedsonar::waterlinkedsonar ALIAS waterlinkedsonar)
target_sources(
    waterlinkedsonar
    PRIVATE
        src/client.cpp
        src/conversions.cpp
        src/curl_transport.cpp
        src/receiver.cpp
        src/rip.cpp
        src/semver.cpp
        src/sntp.cpp
        src/types.cpp
        src/udp_socket.cpp
        ${proto_gen_cc}
)
target_include_directories(
    waterlinkedsonar
    PUBLIC
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
        $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
    PRIVATE ${proto_out_dir}
)
target_compile_features(waterlinkedsonar PUBLIC cxx_std_17)
target_compile_options(
    waterlinkedsonar
    PRIVATE $<$<CXX_COMPILER_ID:GNU,Clang,AppleClang>:-Wall;-Wextra;-Wpedantic>
)
target_link_libraries(
    waterlinkedsonar
    PRIVATE
        protobuf::libprotobuf
        CURL::libcurl
        Snappy::snappy
        ZLIB::ZLIB
        nlohmann_json::nlohmann_json
)
set_target_properties(
    waterlinkedsonar
    PROPERTIES VERSION ${PROJECT_VERSION} SOVERSION ${PROJECT_VERSION_MAJOR}
)

install(
    TARGETS waterlinkedsonar
    EXPORT waterlinkedsonarTargets
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)
install(
    DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include/
    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
    FILES_MATCHING
    PATTERN "*.hpp"
)
install(
    EXPORT waterlinkedsonarTargets
    NAMESPACE waterlinkedsonar::
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/waterlinkedsonar
)
configure_package_config_file(
    cmake/waterlinkedsonarConfig.cmake.in
    ${CMAKE_CURRENT_BINARY_DIR}/waterlinkedsonarConfig.cmake
    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/waterlinkedsonar
)
write_basic_package_version_file(
    ${CMAKE_CURRENT_BINARY_DIR}/waterlinkedsonarConfigVersion.cmake
    COMPATIBILITY SameMajorVersion
)
install(
    FILES
        ${CMAKE_CURRENT_BINARY_DIR}/waterlinkedsonarConfig.cmake
        ${CMAKE_CURRENT_BINARY_DIR}/waterlinkedsonarConfigVersion.cmake
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/waterlinkedsonar
)

if(WATERLINKEDSONAR_BUILD_EXAMPLES)
    add_subdirectory(examples)
endif()
if(BUILD_TESTING AND PROJECT_IS_TOP_LEVEL)
    add_subdirectory(test)
endif()